Experimenting with Energy Monitors

After a spate of high electricity bills and trying to save energy by turning things off randomly I decided to do it the proper and scientific way by experimenting and collecting plenty of data.

In the days of bitcoin mining high energy bills were the norm. Now they miners have all moved to better homes and I am left with myriads of run of the mill appliances. Identifying the energy hungry beasts is not trivial.

Initial attempt at current measurement with DSO-Nano

The Open Energy monitor site has a plethora of ideas and some quite good Arduino and Raspberry Pi based designs for energy monitoring. SeeedStudio also has a couple of designs intended for energy monitoring use with an option to use an LCD or Oled screen, which I quite like. The downside of both these options however is the wireless component. The EmonTx option uses the RFM12/69 as the wireless transciever and the SeeedStudio option uses the nRF24L01+, both options require custom and expensive receiver hardware attached to an always on data-logging system.

Seeedstudio Energy monitor with nRF24

So after a bit of research I decided to roll my own on a breadboard using the ESP8266-12E based NodeMCU module. I started with a basic version is for apparent power only. To keep component count low and the circuit as simple as possible I used an ADS1115 breakout in differential mode eliminating the need for bias resistors. The hard part is getting a licensed electrician to wire up the clamp on current sensor to the main wire coming into the premises. Since we have only 1 channel we are going to monitor overall power rather than power per circuit.

Apparent power energy monitor with ESP8266

After the fact I made a Fritzing diagram showing how-to wire up the prototype on a breadboard. Powering the NodeMCU near the switchboard might be an issue as well, so I installed a DIN rail power socket, this will come in handy for real power measurement later on.

Fritzing diagram of apparent power energy monitor

One of the downsides of the ESP8266 approach however is the high current consumption (300mA or so) of the module and the fact that small block transformers used for voltage sensing will experience power factor shift under this load. This makes powering the system and measuring real power using the same transformer difficult, it can however be done with proper calibration.

NodeMCU Energy Monitor including power supply and voltage sensing

 The next bit is getting proper code to run on the NodeMCU. I chose to use the module in Arduino mode with the excellent work done here. For code inspiration I used Emonlib from the OpenEnergyMonitor project. I made some changes to read the current via the ADS1115 instead of directly via the inbuilt ADC, increased the integration period and patched in a square-root approximation method. The resulting code can be seen below.

	/*
	* This sketch sends ads1115 current sensor data via HTTP POST request to thingspeak server.
	* It needs the following libraries to work (besides the esp8266 standard libraries supplied with the IDE):
	*
	* - https://github.com/adafruit/Adafruit_ADS1X15
	*
	* designed to run directly on esp8266-01 module, to where it can be uploaded using this marvelous piece of software:
	*
	* https://github.com/esp8266/Arduino
	*
	* 2015 Tisham Dhar
	* licensed under GNU GPL
	*/
	#include <ESP8266WiFi.h>
	#include <Wire.h>
	#include <Adafruit_ADS1015.h>
	// replace with your channel's thingspeak API key,
	String apiKey = "XXXXXXXXXXXXX";
	//WIFI credentials go here
	const char* ssid = "XXXXXXXXXXX";
	const char* password = "XXXXXXXXXXXXXXXXXXXXX";
	Adafruit_ADS1115 ads; /* Use this for the 16-bit version */
	const char* server = "api.thingspeak.com";
	WiFiClient client;
	double offsetI;
	double filteredI;
	double sqI,sumI;
	int16_t sampleI;
	double Irms;
	double squareRoot(double fg)
	{
	double n = fg / 2.0;
	double lstX = 0.0;
	while (n != lstX)
	{
	lstX = n;
	n = (n + fg / n) / 2.0;
	}
	return n;
	}
	double calcIrms(unsigned int Number_of_Samples)
	{
	/* Be sure to update this value based on the IC and the gain settings! */
	float multiplier = 0.125F; /* ADS1115 @ +/- 4.096V gain (16-bit results) */
	for (unsigned int n = 0; n < Number_of_Samples; n++)
	{
	sampleI = ads.readADC_Differential_0_1();
	// Digital low pass filter extracts the 2.5 V or 1.65 V dc offset,
	// then subtract this - signal is now centered on 0 counts.
	offsetI = (offsetI + (sampleI-offsetI)/1024);
	filteredI = sampleI - offsetI;
	//filteredI = sampleI * multiplier;
	// Root-mean-square method current
	// 1) square current values
	sqI = filteredI * filteredI;
	// 2) sum
	sumI += sqI;
	}
	Irms = squareRoot(sumI / Number_of_Samples)*multiplier;
	//Reset accumulators
	sumI = 0;
	//--------------------------------------------------------------------------------------
	return Irms;
	}
	void setup() {
	Serial.begin(115200);
	delay(10);
	// We start by connecting to a WiFi network
	Serial.println();
	Serial.println();
	Serial.print("Connecting to ");
	Serial.println(ssid);
	WiFi.begin(ssid, password);
	while (WiFi.status() != WL_CONNECTED) {
	delay(500);
	Serial.print(".");
	}
	Serial.println("");
	Serial.println("WiFi connected");
	Serial.println("IP address: ");
	Serial.println(WiFi.localIP());
	ads.setGain(GAIN_ONE); // 1x gain +/- 4.096V 1 bit = 2mV 0.125mV
	ads.begin();
	}
	void loop() {
	//Serial.print("Differential: "); Serial.print(results); Serial.print("("); Serial.print(trans_volt); Serial.println("mV)");
	double current = calcIrms(2048);
	if (client.connect(server,80)) { // "184.106.153.149" or api.thingspeak.com
	String postStr = apiKey;
	postStr +="&field1=";
	postStr += String(current);
	postStr += "\r\n\r\n";
	client.print("POST /update HTTP/1.1\n");
	client.print("Host: api.thingspeak.com\n");
	client.print("Connection: close\n");
	client.print("X-THINGSPEAKAPIKEY: "+apiKey+"\n");
	client.print("Content-Type: application/x-www-form-urlencoded\n");
	client.print("Content-Length: ");
	client.print(postStr.length());
	client.print("\n\n");
	client.print(postStr);
	}
	client.stop();
	//Serial.println("Waiting...");
	// thingspeak needs minimum 15 sec delay between updates
	delay(20000);
	}

view raw Energy_Monitor.ino hosted with ❤ by GitHub

The data from the monitor gets uploaded every 20seconds or so to Thingspeak. This makes it easy to plot graphs and analyse the data for appliance specific spikes, at the expense of losing control over it and some privacy. If you want to keep it all in house it is better to use something like EmonCMS.

Multi-day energy use graph(uncalibrated)